PL/SQL分外处理

As we all
known,程序的失实一般分为两类:编译错误和周转时不当。其中运行时不当被誉为相当。PL/SQL语句块中拍卖很是的一部分即为十分处理局部。在充足处理局部,可以指定当特定相当暴发时所使用的动作。

PL/SQL有两类别型的特别:内置分外和用户自定义卓殊。

内部,内置相当又分为预定义异常和非预定义相当。

一、内置非凡

首先试举一例来抛砖引玉。

DECLARE
   v_ename varchar2(10);
   v_empno number(4) := &v_empno;
BEGIN
   SELECT ename
     INTO v_ename
   FROM EMP
   WHERE empno = v_empno;
   DBMS_OUTPUT.PUT_LINE('Employee name is '||v_ename);
END;

该语句块通过输入员工的号子来得出员工的全名。当输入的职工编号存在时,输出员工姓名,当员工编号不设有时,会有运行错误。如下所示:

SQL> /
Enter value for v_empno: 7788 
Employee name is SCOTT              -->> 输入的员工编号存在,输出员工姓名

PL/SQL procedure successfully completed.

SQL> /
Enter value for v_empno: 1234
DECLARE
*
ERROR at line 1:
ORA-01403: no data found            -->> 输入的员工编号不存在,报运行时错误
ORA-06512: at line 5

 不问可知,编译器不可以检测运行错误。为在先后中拍卖这序列型的一无是处,必须添加异常处理局部。分外处理局部的语法结构如下:

EXCEPTION
       WHEN EXCEPTION_NAME THEN
             ERROR-PROCESSING STATEMENTS;

在语句块中,很是处理部分位于可进行部分之后,上例可修改如下:

DECLARE
   v_ename varchar2(10);
   v_empno number(4) := &v_empno;
BEGIN
   SELECT ename
     INTO v_ename
   FROM EMP
   WHERE empno = v_empno;
   DBMS_OUTPUT.PUT_LINE('Employee name is '||v_ename);
EXCEPTION
   WHEN NO_DATA_FOUND THEN
   DBMS_OUTPUT.PUT_LINE('There is no such employee');
END;

采取非常处理部分,可以使得程序可以正常截至,而不是畸形终止。同时,输出结果更加面向用户,而不是编程人员。

上述NO_DATA_FOUND即为Oracle预定义非常。

上边列出一部分广泛的预定义分外:

TOO_MANY_ROWS : SELECT INTO重回多行
INVALID_CURSOR :非法指针操作(关闭已经关闭的游标)
ZERO_DIVIDE :除数等于零
DUP_VAL_ON_INDEX :违反唯一性约束
ACCESS_INTO_NULL: 未定义对象
CASE_NOT_FOUND: CASE 中若未包含相应的 WHEN ,并且没有安装 ELSE 时
COLLECTION_IS_NULL: 集合元素未伊始化
CURSER_ALREADY_OPEN: 游标已经开辟
DUP_VAL_ON_INDEX: 唯一索引对应的列上有再次的值
INVALID_NUMBER: 内嵌的 SQL 语句不可以将字符转换为数字
NO_DATA_FOUND: 使用 select into
未回来行,或应用索引表未起先化的因素时
SUBSCRIPT_BEYOND_COUNT:元素下标超越嵌套表或 VARRAY 的最大值
SUBSCRIPT_OUTSIDE_LIMIT: 使用嵌套表或 VARRAY 时,将下标指定为负数
VALUE_ERROR: 赋值时,变量长度不足以容纳实际多少
LOGIN_DENIED: PL/SQL 应用程序连接到 oracle
数据库时,提供了不正确的用户名或密码
NOT_LOGGED_ON: PL/SQL 应用程序在并未连接 oralce
数据库的景色下访问数据
PROGRAM_ERROR: PL/SQL 内部问题,可能需要重装数据字典& pl./SQL 系统包
ROWTYPE_MISMATCH: 宿主游标变量与 PL/SQL 游标变量的回来类型不包容
SELF_IS_NULL: 使用对象类型时,在 null 对象上调用对象方法
STORAGE_ERROR: 运行 PL/SQL 时,超出内存空间
SYS_INVALID_ID: 无效的 ROWID 字符串
TIMEOUT_ON_RESOURCE: Oracle 在等候资源时超时

others可以象征享有特别,oracle预定义的非常在20000以内。

二、 用户自定义很是

常见,在自己的程序里,也许需要处理与所写程序相关的题材。例如,在上个语句块中,需要输入员工编号。平常,希望员工编号是正值。不过无意间,用户输入一个负数。不过,没有生出任何不当,因为变量v_empno被定义为数值类型。这时,你希望自定义很是来拍卖这种场馆,这系列型的异常被称呼用户自定义非凡。在动用该特别往日,必须首先进行宣示。语法结构如下所示:

DECLARE
     exception_name EXCEPTION;
BEGIN
     …
     IF  CONDITION THEN
          RAISE exception_name;
     ELSE
          …
     END IF;
EXCEPTION
     WHEN exception_name THEN
           ERROR-PROCESSING STATEMENTS;
END;

故上例可修改为:

DECLARE
   v_ename varchar2(10);
   v_empno number(4) := &v_empno;
   e_invalid_no exception;
BEGIN
   IF v_empno < 0 THEN
        RAISE e_invalid_no;    -->> 注意:RAISE语句应该与IF语句一起使用,否则,每次执行时,执行权都会转到该语句块的异常处理部分
   ELSE
      SELECT ename
         INTO v_ename
      FROM EMP
      WHERE empno = v_empno;
      DBMS_OUTPUT.PUT_LINE('Employee name is '||v_ename);
   END IF;
EXCEPTION
   WHEN e_invalid_no THEN
   DBMS_OUTPUT.PUT_LINE('Employee number can not be negative');
END;

三、RAISE_APPLICATION_ERROR

     RAISE_APPLICATION_ERROR是oracle提供的一种奇特的内置过程,允许编程人士为一定应用程序创制有意义的错误信息。RAISE_APPLICATION_ERROR过程适用于未命名的用户定义异常。它担负将错误编号和谬误文本关联起来,它的语法为:

     RAISE_APPLICATION_ERROR(error_number,error_message);

   
 error_number是与一定错误新闻相关联的一无是处编号。这些号码的界定在-20999到-20000之内。error_message是大错特错文本,最多包含2048个字符。

     上例可修改为:

DECLARE
   v_ename varchar2(10);
   v_empno number(4) := &v_empno;
BEGIN
   IF v_empno < 0 THEN
        RAISE_APPLICATION_ERROR(-20000,'Employee number can not be negative');
   ELSE
      SELECT ename
         INTO v_ename
      FROM EMP
      WHERE empno = v_empno;
      DBMS_OUTPUT.PUT_LINE('Employee name is '||v_ename);
   END IF;
END;

当输入的员工编号为负数时,运行结果如下所示:

SQL> /
Enter value for v_empno: -1234
DECLARE
*
ERROR at line 1:
ORA-20000: Employee number can not be negative
ORA-06512: at line 6

借助于RAISE_APPLICATION_ERROR过程,编程人士可以按照与Oracle错误一致的章程赶回错误音信。

四、 EXCEPTION_INIT

在上文内置万分中,预定义非常的个数其实是不行有限的,当程序抛出任何不在上述预定义范围内的老大时,该怎么捕捉呢?

例如下例:

DECLARE
   v_deptno  number(2) := &v_deptno;
BEGIN
   DELETE FROM dept
    WHERE deptno= v_deptno;
END;

当部门编号输入10时,大家来探视运行结果:

SQL> /
Enter value for v_deptno: 10
DECLARE
*
ERROR at line 1:
ORA-02292: integrity constraint (SCOTT.FK_DEPTNO) violated - child record found
ORA-06512: at line 4

违反父键约束,可是,大家什么样捕捉此种错误呢?在此间,大家可以用到EXCEPTION_INIT。

使用EXCEPTION_INIT指令,可以将某Oracle错误编号和用户定义卓殊的称呼建立关联。EXCEPTION_INIT指令出现在语句块的宣示部分,如下所示:

DECLARE
      exception_name EXCEPTION;
      PRAGMA EXCEPTION_INIT(exception_name,error_code);

专注,用户定义十分的宣示出现在所运用的EXCEPTION_INIT指令从前,EXCEPTION_INIT指令有六个参数:exception_name和error_code。exception_name是特其它名号,error_code是愿意与该特别建立关联的Oralce错误编号。

上例可修改为:

DECLARE
   v_deptno  number(2) := &v_deptno;
   e_child_exists EXCEPTION;
   PRAGMA EXCEPTION_INIT(e_child_exists,-2292);
BEGIN
   DELETE FROM dept
    WHERE deptno= v_deptno;
EXCEPTION
   WHEN e_child_exists THEN
     DBMS_OUTPUT.PUT_LINE('Delete employees for No.'||v_deptno||' dept first');
END;

平等将单位编号输入为10,来看看结果:

SQL> /
Enter value for v_deptno: 10
Delete employees for No. 10 dept frist

PL/SQL procedure successfully completed.

可以正常捕捉错误!

五、 SQLCODE和SQLERRM

所以Oracle错误都可以拔取OTHERS分外处理程序举办捕获和拍卖,如下例所示:

DECLARE
  v_deptno number(4) := &v_deptno;
  v_dname  varchar2(5);
  v_loc    varchar2(10);
BEGIN
  SELECT dname,loc
    INTO v_dname,v_loc
    FROM dept
  WHERE deptno = v_deptno;
  DBMS_OUTPUT.PUT_LINE(v_dname||','||v_loc);
EXCEPTION
  WHEN OTHERS THEN
     DBMS_OUTPUT.PUT_LINE('An error has occurred');
END;

当输入10看作机关编号的值时,我们来探视输出:

SQL> /
Enter value for v_deptno: 10
An error has occurred

PL/SQL procedure successfully completed.

上述输出表达,在程序运行时发生一个荒谬。如果你对表结构及数据不是很领悟的话,你很难精通这一个错误是怎么着,以及是咋样来头促成错误发生的。也许在运行时,dept表中不存在对应的机关编号,或者SELECT
INTO语句所造成的数据类型匹配问题。即使这只是一个简练地例子,但依然可能会时有爆发过多竟然的周转错误。

当然,你永远不可以领会程序执行时有所可能暴发的运行错误,因而,最好在自己的次序中添加OTHERS万分处理程序。为改革自己程序的那些处理接口,Oracle提供了五个放置函数-SQLCODE和SQLERRM-用于贯彻OTHERS非凡处理程序。SQLCODE函数会回来Oracle错误编号,SQLERRM函数再次回到错误音信。

修改上例如下:

DECLARE
  v_deptno number(4) := &v_deptno;
  v_dname  varchar2(5);
  v_loc    varchar2(10);
BEGIN
  SELECT dname,loc
    INTO v_dname,v_loc
    FROM dept
  WHERE deptno = v_deptno;
  DBMS_OUTPUT.PUT_LINE(v_dname||','||v_loc);
EXCEPTION
  WHEN OTHERS THEN
     DBMS_OUTPUT.PUT_LINE(SQLCODE||chr(10)||SQLERRM);  -->> chr(10)代表回车键
END;

如出一辙,当输入10作为机关编号时,看看输出:

SQL> / 
Enter value for v_deptno: 10
-6502
ORA-06502: PL/SQL: numeric or value error: character string buffer too
small

PL/SQL procedure successfully completed.

诸如此类可捕捉任何运行时不当的荒谬编号和谬误音讯 

总结:

     1> 预定义卓殊的错误代码出名称,譬如上文提到的NO_DATA_FOUNG

     2>
非预定义非常只有错误代码,没有称谓,如上文提到的ora-02292。这时可以通过EXCEPTION_INIT编译指令举办错误代码和名称的关系。

     3>
当PL/SQL语句块的可进行部分现身某个运行错误时,会抛出不同档次的百般。可是,运行错误也说不定发生在语句块的宣示部分仍旧特别处理部分。控制在这多少个环境下充足抛出艺术的条条框框称为万分传播。

     4>
当PL/SQL语句块的扬言部分仍旧特别处理局部出现运行错误时,该语句块的特别处理部分不能够捕获此项错误。假如不设有外部语句块,该程序执行会截至,并将执行权转到主机环境。假如存在外部语句块,该特别会及时传播到表面语句块。如下例所示:

--outer block
BEGIN
   --inner block
   DECLARE
      v_test CHAR(3) := 'ABC';
   BEGIN
      v_test := '1234';
      DBMS_OUTPUT.PUT_LINE('v_test: '||v_test);
   EXCEPTION
      WHEN INVALID_NUMBER OR VALUE_ERROR THEN
          v_test := 'ABCD';
          DBMS_OUTPUT.PUT_LINE('An error has occurred in the inner block');
   END;
EXCEPTION
   WHEN INVALID_NUMBER OR VALUE_ERROR THEN
       DBMS_OUTPUT.PUT_LINE('An error has occurred in the program');
END;

当执行时,得到如下输出:

SQL> /
An error has occurred in the program

PL/SQL procedure successfully completed.

最后试举一例练练思维:

DECLARE
   my_error1 EXCEPTION;
   PRAGMA EXCEPTION_INIT(my_error1, -20001);
   my_error2 EXCEPTION;
   PRAGMA EXCEPTION_INIT(my_error2, -20002);
BEGIN
  IF 1=2  THEN
    raise_application_error(-20001,'err_1');
  ELSE
    raise_application_error(-20002,'err_2');
  END IF;
EXCEPTION
  WHEN NO_DATA_FOUND THEN
    DBMS_OUTPUT.PUT_LINE('Not found');
  WHEN TOO_MANY_ROWS THEN
    DBMS_OUTPUT.PUT_LINE('More data');
  WHEN MY_ERROR1 THEN
    dbms_output.put_line('This is a err_1 test');
  WHEN MY_ERROR2 THEN
    dbms_output.put_line('This is a err_2 test');
END;

 

相关文章